void loop ()
{
    EthernetClient client;
    File descfic;
    File descmenu;


    // Regarde si un client est connecté et attend une réponse
    client = serveur.available ();

    // si c'est le cas, quelqu'un est connecté
    if (client)
    {
        // récupérer ce qu'il a envoyé
        lire_trame_client (client, url, sizeof (url));

        // si aucun nom de fichier ne figure dans l'url
        if (! url [1])
            // mettre le nom du fichier d'accueil
            strcpy (url, "indexb.htm");

        // tenter d'accéder à au fichier HTML
        descfic = SD.open (url, FILE_READ);

        // si on n'a pas réussi, tenter la page d'erreur
        if (! descfic)
            descfic = SD.open (F("/err404.htm"), FILE_READ);

        // envoi de l'entête de la page web
        envoie_entete_reponse (client, url);

        // si on accède au fichier html
        if (descfic)
        {
            // envoi du début de la page
            copie_jusque_chaine (descfic, client, "XXXMENU");

            // tenter d'accéder à au fichier menu
            descmenu = SD.open ("menu.htm", FILE_READ);

            // si on a réussi, rajouter le menu
            if (descmenu)
            {
                 copie_jusque_fin (descmenu, client);
                 descmenu.close ();
            }
            // sinon message d'erreur
            else
                envoieln_trame (F("Fichier menu manquant"), client);

            // envoi de la fin de la page
            copie_jusque_fin (descfic, client);

            // ferner le fichier HTML
            descfic.close ();
        }
        // sinon message d'erreur
        else
            client.println (F("Probleme probable d'acces a la carte SD"));

        Serial.println (F("Page envoyée\n"));

        // Donne le temps au client de prendre les données
        delay (10);

        // Ferme la connexion avec le client
        client.stop ();
    }
}